EEE 51 Tutorial 6

A Two-Stage Amplifier

In many applications, (1) the amplifier gain requirement is larger than the gain a single transistor can provide, and (2) the input and output impedance requirements cannot be met simultaneously by a single amplifier. These gain and impedance requirements usually necessitates the use of multi-stage amplifiers.

For example, if we need a voltage gain of greater than 5000, we need more than one common-emitter amplifier. Let’s build a 2-stage amplifier composed of two common-emitter amplifiers, as shown below:

Figure 1: A two-stage amplifier composed of two common-emitter amplifiers (CE-CE amplifier).

We can use the first stage to set the DC input voltage of the second stage. Thus, we need the DC output voltage of first stage to be equal to the DC base-emitter voltage of the second stage:

$V_{CE1}=V_{BE5}$

Ignoring the effect of $I_{B5}$ on $I_{C2}$ , we can set $I_{C1}=I_{C5}=1\mathrm{mA}$ , and the DC output voltage of the second stage to $V_{OUT}=\tfrac{1}{2}\cdot V_{CC}=2.5\mathrm{V}$ , we get:

$V_{BE5}=n_5\cdot V_T\cdot \ln\left(\frac{I_{C5}}{I_{S5}\cdot\left(1+\frac{V_{CE5}}{\left|V_{A5}\right|}\right)}\right)=662.22\mathrm{mV}$

Note that $V_{CE1}=V_{BE5}> V_{CE,sat}$ , so transistor Q1 is still in the forward-active region. Then

$V_{BE1}=n_1\cdot V_T\cdot \ln\left(\frac{I_{C1}}{I_{S1}\cdot\left(1+\frac{V_{BE5}}{\left|V_{A1}\right|}\right)}\right)=670.43\mathrm{mV}$

Note that since $V_{CE1}\approx V_{CE4}$ , then $I_{C1}\approx I_{C4}$ . Thus, we can calculate the value of Rm2 as:

$R_{m2} = \frac{V_{CC}-V_{BE4}}{I_{C4} + I_{B4} + I_{B1}}=4.267\mathrm{k\Omega}$

To get the value of Rm, we need $V_{EB2}$ and $I_{C3}$ :

$V_{EB2}=n_2\cdot V_T\cdot \ln\left(\frac{I_{C2}}{I_{S2}\cdot \left(1+\frac{V_{CC}-V_{CE1}}{\left|V_{A2}\right|}\right)}\right)=691.36\mathrm{mV}$

$I_{C3}=I_{C2} \cdot \frac{1 + \frac{V_{EB2}}{\left|V_{A3}\right|}}{1 + \frac{V_{CC}-V_{CE1}}{\left|V_{A2}\right|}}=675.72\mathrm{\mu A}$

Thus,

$R_m = \frac{V_{CC}-V_{EB2}}{I_{C3} + I_{B3} + I_{B2}}=6.312\mathrm{k \Omega}$

Using the same procedure to get Rm3, but with $V_{EC6}=V_{OUT}=\tfrac{1}{2}\cdot V_{CC}$ and $V_{EC7}=V_{EB6}$ , we get:

$I_{C7}=I_{C6} \cdot \frac{1 + \frac{V_{EB6}}{\left|V_{A7}\right|}}{1 + \frac{V_{CC}-V_{CE1}}{\left|V_{A6}\right|}}$

and, similar to tutorial 5,

$R_{m3}=\frac{V_{CC}-V_{EC7}}{I_{C7} + I_{B7} + I_{B6}}=5.277\mathrm{k \Omega}$

We can then create a netlist to describe our 2-stage amplifier:

* Common Emitter Amplifier with Current Mirror Bias
* LPA 2020-04-16

.include 2N390X.lib
.options savecurrents

Vcc		v1	0		dc 5.0

* first stage
* the pnp current mirror
Q2		vout1 b2 v1	2N3906
Q3		b2 b2 v1	2N3906

* the bias resistor
Rm		b2 0		6.312k

* the npn gain transistor
Q1		vout1 b1 0	2N3904

Vin 	b1 b1a		dc 0 sin(0 125u 1k)

* the npn current mirror
Q4		b1a b1a 0	2N3904
Rm2		v1 b1a		4.267k

* second stage
* the pnp current mirror
Q6		vout b22 v1	2N3906
Q7		b22 b22 v1	2N3906

* the bias resistor
Rm3		b22 0		5.277k

* the npn gain transistor
Q5		vout vout1 0	2N3904


.control

dc Vin -0.5m 0.5m 5u
wrdata amp_2stage_transfer_sim.dat v(vout) @Q1[ic] @Q5[ic]

tran 1u 5m 
wrdata amp_2stage_transient_sim.dat v(vout) v(b1) v(vout1)

.endc

.end

Using this Python script, we can run the simulation, read-in the data, and plot the results.

Figure 2 shows the DC transfer characteristics of the 2-stage amplifier. Note that since each common-emitter amplifier is an inverting amplifier, cascading them produces a non-inverting compound amplifier.

Figure 2: The DC transfer characteristic of the 2-stage common-emitter amplifier.

Note that we expect a slightly smaller $I_{C1}$ compared to $I_{C5}$ since transistor Q2 is also supplying the base current of transistor Q5. Looking at the x-axis of Figure 2, we can see that the gain is significantly larger than the single-stage amplifier. Figure 3 shows a plot of the small signal gain.

Figure 3: The small signal gain of the 2-stage amplifier using common-emitter stages.

Once again, due to the limitations of the ideal transistor BJT model, we do expect that the errors in our small signal analysis will accumulate as we increase the complexity of our circuit.

Note that we have ignored the effects of the small signal input resistance of the second stage. We can correct for this by re-calculating the small signal gain as:

$a_v = \left(-g_{m1}\cdot \left(r_{o1} \| r_{o2} \| r_{\pi 5}\right) \right)\cdot \left(-g_{m5}\cdot \left(r_{o5} \| r_{o6} \right) \right)$

If we plug-in our values for $r_{o1}$ , $r_{o2}$ , and $r_{\pi 5}$ , this loading effect reduces the gain by a factor of 0.6. Thus, if we use our simulated values for small signal gain from tutorial 5 (~150 per stage), we get $0.6 \cdot \left(-150\right) \cdot \left(-150\right) = 13500$ , which is in the same ballpark as our simulation results.

The results of our transient analysis is shown in Figure 4. Again note that the 2-stage amplifier is a non-inverting amplifier.

Figure 4: The simulated transient response of our 2-stage compound amplifier.

It turns out we were extremely lucky in biasing our 2-stage amplifier since (1) small changes in the first stage’s DC output voltage can drastically change the transfer characteristics, and (2) the output voltage of the first stage is very sensitive to its input DC voltage.

In real-world amplifiers, we can either control the output voltage precisely using feedback, or we can use circuits that can accept a wide range of input DC voltages, such as differential circuits.

End of Tutorial 6

Congratulations! You have just biased the first and second stage of a 2-stage compound CE-CE amplifier using current mirrors, and examined its small-signal behavior.